contract-java-example/backend/build.gradle

buildscript {
    repositories{
        mavenCentral()
        mavenLocal()
    }
    dependencies {
        classpath "org.bdware.bdcontract:simple-ypk-packer:0.3.0"
        classpath "org.bdware.bdcontract:ypk-deploy-tool:0.4.0"
    }
}
plugins {
    id 'java'
    id 'java-library'
}

tasks.withType(JavaCompile) {
    options.compilerArgs << '-Xlint:none'
    options.compilerArgs << '-Xlint:deprecation' << "-Werror"
}

sourceSets {
    main {
        java {
            srcDirs 'src/main/java'
        }
        resources {
            srcDir 'src/main/resources'
        }
    }
    test {
        java {
            srcDir 'src/test/java'
        }
        resources {
            srcDir 'src/test/resources'
        }
    }
}

dependencies {
    api 'org.apache.logging.log4j:log4j-core:2.17.2'
    api 'org.apache.logging.log4j:log4j-api:2.17.2'
    implementation fileTree(dir: 'cplibs', include: '*.jar')
    implementation fileTree(dir: 'cplibs/lib/', include: '*.jar')
    testImplementation 'junit:junit:4.13.2'
}

task copyLibs(type: Copy) {
    from configurations.runtimeClasspath
    into "./build/output/libs/"
}

task copyYJS(type: Copy) {
    from "./yjs"
    into "./build/output/"
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
    archiveClassifier = 'sources'
}
task copyAssets(type: Copy) {
    from "../front"
    into "./build/output/assets/"
}

task copyJar(type: Copy, dependsOn: [":backend:jar", ":backend:copyLibs"]) {
    from "./build/libs/$project.name-${project.version}.jar"
    into "./build/output"
    rename { String fileName -> "sc-example.jar" }
    doFirst {
        println "copyJar start"
    }
}
def reltivePath = "./backend"
//reltivePath="."
def currVersion = "1.1.0"
task grepCP (dependsOn:["copyJar"]){
    doLast {
        org.bdware.datanet.YPKPacker.grepCPLibWithFilter("${reltivePath}/cplibs/libs","${reltivePath}/build/output/libs","${reltivePath}/grepcp.list")
    }
}

task buildZip(type: Zip, dependsOn: ["copyAssets", "copyJar", "copyYJS","grepCP"]) {
    from './build/output/'
    duplicatesStrategy = DuplicatesStrategy.INCLUDE
    archiveFileName = 'contractexample.zip'
    destinationDirectory = file('build/')
}

task buildYPK(dependsOn: ["buildZip"]) {
    doLast {
        org.bdware.datanet.YPKPacker.staticPack("${reltivePath}/build/contractexample.zip", "${reltivePath}/build/contractexample-${currVersion}.ypk")
    }
}
task deploy(dependsOn: ["buildYPK"]){
    doLast {
        org.bdware.ypkdeploy.HTTPTool.batchRun("./backend/deployconfig.json", true)
    }
}